[GH-ISSUE #192] EBNF grammar #2845

New Issue

GiteaMirror · 2026-04-25T16:51:07-05:00

GiteaMirror commented

2026-04-25 16:51:07 -05:00

Originally created by @christianhujer on GitHub (Apr 14, 2014).
Original GitHub issue: https://github.com/semver/semver/issues/192

The Semantic Versioning Spec could have an EBNF grammar.

Here it is, according to http://www.w3.org/TR/xml/#sec-notation.

version ::= MAJOR '.' MINOR '.' PATCH ('-' PRE)? ('+' BUILD)?
MAJOR ::= decimalnumber
MINOR ::= decimalnumber
PATCH ::= decimalnumber
PRE ::= string
BUILD ::= string
string ::= [0-9A-Za-z-]+
decimalnumber ::= [0-9]+

Originally created by @christianhujer on GitHub (Apr 14, 2014). Original GitHub issue: https://github.com/semver/semver/issues/192 The Semantic Versioning Spec could have an EBNF grammar. Here it is, according to http://www.w3.org/TR/xml/#sec-notation. version ::= MAJOR '.' MINOR '.' PATCH ('-' PRE)? ('+' BUILD)? MAJOR ::= decimalnumber MINOR ::= decimalnumber PATCH ::= decimalnumber PRE ::= string BUILD ::= string string ::= [0-9A-Za-z-]+ decimalnumber ::= [0-9]+

GiteaMirror closed this issue

2026-04-25 16:51:07 -05:00

GiteaMirror commented

2026-04-25 16:51:08 -05:00

@rlidwka commented on GitHub (Apr 14, 2014):

it's much more complex than that...

@rlidwka commented on GitHub (Apr 14, 2014): it's much more complex than that...

GiteaMirror commented

2026-04-25 16:51:09 -05:00

@bessarabov commented on GitHub (Apr 14, 2014):

Just in case one hasn't seen it. There is BNF grammar for SemVer: https://github.com/mojombo/semver/blob/master/semver.md#backusnaur-form-grammar-for-valid-semver-versions

@bessarabov commented on GitHub (Apr 14, 2014): Just in case one hasn't seen it. There is BNF grammar for SemVer: https://github.com/mojombo/semver/blob/master/semver.md#backusnaur-form-grammar-for-valid-semver-versions

GiteaMirror commented

2026-04-25 16:51:09 -05:00

@christianhujer commented on GitHub (Apr 17, 2014):

Just found a flaw.
decimalnumber should actually be, to disallow leading zeros:
decimalnumber ::= '0' | [1-9] [0-9]+
I've taken a look at the BNF grammar for SemVer. It is quite verbose because it is plain old BNF, which doesn't have quantifiers and character groups, unlike simple EBNF from the W3C.
But I do not care which BNF language as long as there is a BNF, any BNF is fine with me :)

@christianhujer commented on GitHub (Apr 17, 2014): Just found a flaw. decimalnumber should actually be, to disallow leading zeros: decimalnumber ::= '0' | [1-9] [0-9]+ I've taken a look at the BNF grammar for SemVer. It is quite verbose because it is plain old BNF, which doesn't have quantifiers and character groups, unlike simple EBNF from the W3C. But I do not care which BNF language as long as there is a BNF, any BNF is fine with me :)

GiteaMirror commented

2026-04-25 16:51:10 -05:00

@FichteFoll commented on GitHub (Apr 21, 2014):

FWIW, here is a regular expression I used for my Python implementation. It's not 2.0.0-comform because I allow empty build and pre-release fields to make version selectors more simple but otherwise it should be correct. Furthermore, I added a "whitespace detection" to the regex to allow extracting it from a string, but that doesn't matter when enclosing with ^$ anyway (like I did 2 lines later).

@FichteFoll commented on GitHub (Apr 21, 2014): FWIW, [here](https://github.com/FichteFoll/pysemver/blob/98cc9633e934b2e1817fb26af826af70d4cb1b0a/semver.py#L125-L139) is a regular expression I used for my Python implementation. It's not 2.0.0-comform because I allow empty build and pre-release fields to make version selectors more simple but otherwise it should be correct. Furthermore, I added a "whitespace detection" to the regex to allow extracting it from a string, but that doesn't matter when enclosing with `^$` anyway (like I did 2 lines later).

GiteaMirror commented

2026-04-25 16:51:10 -05:00

@gvlx commented on GitHub (Jun 27, 2018):

Here it is.

Please comment and correct.

@gvlx commented on GitHub (Jun 27, 2018): [Here it is](https://github.com/semver/semver.org/issues/59#issuecomment-393560776). Please comment and correct.

GiteaMirror commented

2026-04-25 16:51:11 -05:00

@glebec commented on GitHub (Oct 2, 2018):

@gvlx my corrections:

PreReleaseIdentifier had a spurious + on NumericIdentifier
AlphaNumericIdentifier cannot parse as IdentifierCharacter* NonNumericCharacter ... b/c IdentifierCharacter* includes NonNumericCharacter. So a typical parser would consume all of the input using IdentifierCharacter* and then fail because there is no NonNumericCharacter to consume. The correct version is NumericCharacter* NonNumericCharacter ....

Version ::= VersionCore ('-' PreRelease)? ('+' Build)?

VersionCore ::= Major '.' Minor '.' Patch
Major ::= NumericIdentifier  
Minor ::= NumericIdentifier  
Patch ::= NumericIdentifier  
PreRelease ::= CompoundPreReleaseIdentifier 
Build      ::= CompoundBuildIdentifier 

CompoundPreReleaseIdentifier ::= PreReleaseIdentifier ('.' PreReleaseIdentifier)*
CompoundBuildIdentifier      ::= BuildIdentifier      ('.' BuildIdentifier)*

PreReleaseIdentifier     ::= AlphaNumericIdentifier | NumericIdentifier
BuildIdentifier          ::= IdentifierCharacter+

NumericIdentifier        ::= '0' | ( PositiveNumeric NumericCharacter* )
AlphaNumericIdentifier   ::= NumericCharacter* NonNumericCharacter IdentifierCharacter*

IdentifierCharacter ::= NonNumericCharacter | NumericCharacter

NonNumericCharacter ::= [A-Za-z-]
NumericCharacter    ::= '0' | PositiveNumeric
PositiveNumeric     ::= [1-9]

@glebec commented on GitHub (Oct 2, 2018): @gvlx my corrections: - `PreReleaseIdentifier` had a spurious `+` on `NumericIdentifier` - `AlphaNumericIdentifier` cannot parse as `IdentifierCharacter* NonNumericCharacter ...` b/c `IdentifierCharacter*` includes `NonNumericCharacter`. So a typical parser would consume all of the input using `IdentifierCharacter*` and then fail because there is no `NonNumericCharacter` to consume. The correct version is `NumericCharacter* NonNumericCharacter ...`. ```ebnf Version ::= VersionCore ('-' PreRelease)? ('+' Build)? VersionCore ::= Major '.' Minor '.' Patch Major ::= NumericIdentifier Minor ::= NumericIdentifier Patch ::= NumericIdentifier PreRelease ::= CompoundPreReleaseIdentifier Build ::= CompoundBuildIdentifier CompoundPreReleaseIdentifier ::= PreReleaseIdentifier ('.' PreReleaseIdentifier)* CompoundBuildIdentifier ::= BuildIdentifier ('.' BuildIdentifier)* PreReleaseIdentifier ::= AlphaNumericIdentifier | NumericIdentifier BuildIdentifier ::= IdentifierCharacter+ NumericIdentifier ::= '0' | ( PositiveNumeric NumericCharacter* ) AlphaNumericIdentifier ::= NumericCharacter* NonNumericCharacter IdentifierCharacter* IdentifierCharacter ::= NonNumericCharacter | NumericCharacter NonNumericCharacter ::= [A-Za-z-] NumericCharacter ::= '0' | PositiveNumeric PositiveNumeric ::= [1-9] ```

GiteaMirror commented

2026-04-25 16:51:12 -05:00

@gvlx commented on GitHub (Oct 2, 2018):

The EBNF has been corrected by @glebec on https://github.com/semver/semver/issues/192#issuecomment-426123552 .

This issue should now be closed.

@gvlx commented on GitHub (Oct 2, 2018): The EBNF has been corrected by @glebec on https://github.com/semver/semver/issues/192#issuecomment-426123552 . This issue should now be closed.

GiteaMirror commented

2026-04-25 16:51:13 -05:00

@jwdonahue commented on GitHub (Oct 8, 2018):

@christianhujer , unless you have further questions, can you please close this issue at your earliest possible convenience?

@jwdonahue commented on GitHub (Oct 8, 2018): @christianhujer , unless you have further questions, can you please close this issue at your earliest possible convenience?

GiteaMirror commented

2026-04-25 16:51:13 -05:00

@ebkalderon commented on GitHub (Sep 4, 2019):

@christianhujer Looks like the EBNF grammar has already been merged into master. Can this issue be closed?

@ebkalderon commented on GitHub (Sep 4, 2019): @christianhujer Looks like the EBNF grammar has already been merged into `master`. Can this issue be closed?

Sign in to join this conversation.

1 Participants

Notifications

Due Date

No due date set.

Dependencies

No dependencies set.

Reference: github-starred/semver#2845